Magma V2.15-13    Sun Jan 10 2010 04:10:45 on emory    [Seed = 3099276670]
Type ? for help.  Type <Ctrl>-D to quit.
> G<a,b> := Group< a,b | a^2, b^3, (a*b)^13, (a,b)^4 >;
> AQInvariants( G );                                     //shows G is perfect
[]
> LI := LowIndexSubgroups( G, 26 );
> S := LI[10]; S;                                       //S has index 26 in G
Finitely presented group S on 3 generators
Index in group G is 26 = 2 * 13
Generators as words in group G
    S.1 = a
    S.2 = b * a * b * a * b^-1
    S.3 = b^-1 * a * b * a * b * a * b * a * b^-1 * a * b * a * b * a * b^-1 * a
    * b
> h1, P := CosetAction( G, S ); ChiefFactors( P );     
    G
    |  A(2, 3)                = L(3, 3)
    *
    |  Cyclic(2) (12 copies)
    1
> #Complements( P, pCore(P,2) );  //the max normal 2-sgp is complemented in P
2
> hbar, PP := CosetAction( G, LI[2] ); #PP;         //LI[2] has index 13 in G
5616
> KK := Kernel( hbar ); Index( G, KK ); Index( P, h1(KK) );
5616
5616
> KK := Rewrite( G, KK : Simplify:=false );
> _ := pQuotient( KK, 2, 2 : Print:=1 );           //shows that KK = (C_2)^12

Lower exponent-2 central series for KK

Group: KK to lower exponent-2 central class 1 has order 2^12

Group completed. Lower exponent-2 central class = 1, Order = 2^12
> T := LI[6];                                           //T has index 26 in G
> h2, Q := CosetAction( G, T ); ChiefFactors( Q );
    G
    |  A(1, 25)               = L(2, 25)
    1
> L := Kernel( h2 ); L := Rewrite( G, L : Simplify:=false );
> AQInvariants( L );
[]
> x := (a*b)^2*a*b^-1; x in S; Order( h1(x) ); Order( h2(x) );
true
16
13
> //Compute the inverse image I of a Sylow 2-subgroup P_2 x Q_2 of P x Q.
> //This is not completely straightforward, but may be done as follows.
> //(It is convenient to choose I such that x^13 is in I$, which is the 
> //purpose of the explicit for loop in the following code.)
> P2 := Sylow( P, 2 );
> for g in Transversal( P, P2 ) do
for>   if h1(x^13) in P2^g then P2 := P2^g; break; end if;
for> end for;
> h1(x^13) in P2;
true
> m1 := CosetAction( P, P2 );
> IP2 := sub< G | h1*m1 >; Index( G, IP2 ); IP2 := Rewrite( G, IP2 );
351
> h2r := hom< IP2 -> Q | [ h2(IP2.i) : i in [1..Ngens(IP2)] ] >;
> Q2 := Sylow( Q, 2 ); m2 := CosetAction( Q, Q2 );
> I := sub< IP2 | h2r*m2 >; Index( IP2, I );
975
> I := Rewrite( IP2, I : Simplify:=false );
> _, pqm := pQuotient( I, 2, 12 : Print:=1 );

Lower exponent-2 central series for I

Group: I to lower exponent-2 central class 1 has order 2^6

Group: I to lower exponent-2 central class 2 has order 2^10

Group: I to lower exponent-2 central class 3 has order 2^13

Group: I to lower exponent-2 central class 4 has order 2^15

Group: I to lower exponent-2 central class 5 has order 2^16

Group: I to lower exponent-2 central class 6 has order 2^17

Group: I to lower exponent-2 central class 7 has order 2^18

Group: I to lower exponent-2 central class 8 has order 2^19

Group: I to lower exponent-2 central class 9 has order 2^20

Group completed. Lower exponent-2 central class = 9, Order = 2^20
> Factorisation( #P2 * #Q2 ); 
[ <2, 19> ]
> y := I!IP2!(x^13); Order( pqm( y ) );
16
> S := Rewrite( G, S ); x := S!x;
> Index( S, sub<S|x> : CosetLimit:=10^8, Hard:=true, Mendelsohn:=true );
66355200
> [ pMultiplicator( P, p ) : p in [2,3,13] ];
[
    [ 2, 2 ],
    [ 1 ],
    [ 1 ]
]
> [ pMultiplicator( Q, p ) : p in [2,3,5,13] ];
[
    [ 2 ],
    [ 1 ],
    [ 1 ],
    [ 1 ]
]
> //We determine the structure of the normal subgroup of order 2^13.
> //To build the subgroup we choose random elements in I and test them for 
> //membership in the subgroup, until we have the complete subgroup.
> C := pCore(P,2); elts := [];
> repeat
repeat>   repeat z := Random(I,10,15); until h1(z) in C and h2r(z) eq Id(Q);
repeat>   Append(~elts, pqm(z)); U := sub< Image(pqm) | elts >;
repeat> until #U eq 2^13;
> IsExtraSpecial(U); 
true
> FormType( ActionGroup( GModule( P, C ) ) );
orthogonalminus
> Ep := ExtraSpecialGroup( 2, 6 : Type := "+" );
> Em := ExtraSpecialGroup( 2, 6 : Type := "-" );
> #{ x : x in Ep | Order(x) eq 2 }; #{ x : x in Em | Order(x) eq 2 };
4159
4031
> #{ x : x in U | Order(x) eq 2 };
4031
> //We now address H
> H<c,d> := Group< c,d | c^2, d^3, (c*d)^13 * (c,d)^-4 >;
> AQInvariants( H );
[]
> Index( H, sub< H | c*d, (c,d) > );
1

Total time: 1550.490 seconds, Total memory usage: 2562.94MB